plugins {
    id("com.android.application")
    id("org.jetbrains.kotlin.android")
}

android {
    namespace = "cn.ilapage.goauto.agent"
    compileSdk = 34

    defaultConfig {
        applicationId = "cn.ilapage.goauto.agent"
        minSdk = 23
        targetSdk = 34
        versionCode = 72
        versionName = "0.9.59"

        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"

		val configuredServerUrl = providers.environmentVariable("GOAUTO_SERVER_URL")
			.orElse(providers.gradleProperty("GOAUTO_SERVER_URL"))
			.orElse("")
			.get()
			.replace("\\", "\\\\")
			.replace("\"", "\\\"")
		buildConfigField("String", "DEFAULT_SERVER_URL", "\"$configuredServerUrl\"")
    }

	buildFeatures {
		buildConfig = true
	}

    buildTypes {
        release {
            isMinifyEnabled = false
            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
        }
    }

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
    }

    kotlinOptions {
        jvmTarget = "17"
    }

    sourceSets {
        getByName("test").resources.srcDir(rootProject.file("../contracts"))
    }
}

dependencies {
    implementation("androidx.appcompat:appcompat:1.7.0")
    implementation("androidx.fragment:fragment-ktx:1.8.5")
    implementation("androidx.swiperefreshlayout:swiperefreshlayout:1.1.0")
    implementation("com.google.android.material:material:1.12.0")

    testImplementation("junit:junit:4.13.2")
    testImplementation("org.json:json:20240303")
    testImplementation("org.xerial:sqlite-jdbc:3.46.1.0")
}